/* ----
   MakeShowAllInTreeView.CMD
   Set SHOWALLINTREEVIEW=YES recursively for all subfolders
   CoCo, 06/06/1999
*/

PARSE ARG Folder .

Folder = STRIP(Folder)

IF LENGTH(Folder) = 0 THEN
   SIGNAL Syntax

CR = '0d'x
BarLen  = 60

/* ----
   Load needed RxUtil-functions 
*/

IF RxFuncQuery('SysCreateObject') THEN
   rc = RxFuncAdd('SysCreateObject', 'RexxUtil', 'SysCreateObject')

IF RxFuncQuery('SysFileTree') THEN
   rc = RxFuncAdd('SysFileTree', 'RexxUtil', 'SysFileTree')

IF RxFuncQuery('SysCurState') THEN
   rc = RxFuncAdd('SysCurState', 'RexxUtil', 'SysCurState')

/* ----
   Get folders via SysFileTree
*/

Cursor = SysCurState('OFF')

SAY 'Setting SHOWALLINTREEVIEW recursively for 'Folder
SAY 'Fetching foldernames'

/* Append missing backslash, if needed */
IF RIGHT(Folder,1) \= '\' THEN DO
   rc = SysFileTree(Folder'\*', 'Files','DSO')
   END
  ELSE DO
   rc = SysFileTree(Folder'*', 'Files','DSO')
END

IF Files.0 = 0 THEN DO
   SAY 'No folders were found'
   SIGNAL Error
END

IF rc \= 0 THEN DO 
   SAY 'SysFileTree failed : 'rc
   SIGNAL Error
END

/* ----
   Prepare progressbar
*/
C = 0
A = Files.0 / BarLen
B = A
Z = 0

/* ----
   Process all folders we found
*/

SAY 'Processing 'Files.0' folders'

DO I = 1 TO BarLen
   rc = CHAROUT(,'°')
END
rc = CHAROUT(,CR)

DO I = 1 TO Files.0
   Folder         = Files.I 
   FolderLocation = Folder
   FolderLocation = LEFT(FolderLocation, LASTPOS("\", FolderLocation)-1)
   IF LENGTH(FolderLocation)=2 THEN FolderLocation = FolderLocation'\'
   FolderName     = SUBSTR(Folder, LASTPOS("\", Folder)+1)
   Call DispStat
   rc = SysCreateObject("WPFolder", FolderName,  FolderLocation, "ALWAYSSORT=YES;ICONVIEW=NONFLOWED, MINI;MENUBAR=NO;SHOWALLINTREEVIEW=YES", "u")
   IF  rc \=1 THEN SAY 'Folder could not be updated...'
END

Call DispStat

EXIT

Syntax:
 SAY 'MakeShowAllInTreeView - Set SHOWALLINTREEVIEW recursively'
 SAY 'Syntax     :    MakeShowAllInTreeView <StartFolder>'
 SAY 'Parameters :    <StartFolder>'
 SAY '                Folder to start with for recursive'
 SAY '                change of SHOWALLINTREEVIEW-attribute'
EXIT

Error:
 SAY 'Exiting ...'
EXIT

DispStat:
    C = C + 1
    DO WHILE (C >= A)
       Z = Z + 1
       IF Z <= BarLen THEN rc = CHAROUT(,'Û')
       A  = A + B
    END  
RETURN